The Blog of Josh Stodola

Imports System.Collections.Generic
Imports System.IO
Imports System.Xml
Imports System.Xml.Schema

Public Class XmlValidator

    Private ErrorList As List(Of String)
    Private SchemaList As List(Of String)
    Private SchemaReaderSettings As XmlReaderSettings
    Private SchemaValidation As ValidationEventHandler

    ''' <summary>
    ''' Instantiates the XmlValidator class
    ''' </summary>
    Public Sub New()
        SchemaList = New List(Of String)
        SchemaReaderSettings = New XmlReaderSettings()
        SchemaValidation = New ValidationEventHandler(AddressOf ValidationHandler)
    End Sub

    ''' <summary>
    ''' Settings applied to the schema(s) when validating
    ''' </summary>
    Public ReadOnly Property SchemaSettings() As XmlReaderSettings
        Get
            Return SchemaReaderSettings
        End Get
    End Property

    ''' <summary>
    ''' List of absolute paths for each schema to validate against
    ''' </summary>
    Public ReadOnly Property Schemas() As List(Of String)
        Get
            Return SchemaList
        End Get
    End Property

    ''' <summary>
    ''' Validates the given XML string against the schema(s)
    ''' </summary>
    ''' <param name="RawXml">The raw XML data to validate</param>
    ''' <returns>A generic list of error messages</returns>
    Public Function ValidateXml(ByVal RawXml As String) As List(Of String)
        ErrorList = New List(Of String)

        If Me.Schemas.Count > 0 Then
            Dim ReaderSettings As New XmlReaderSettings()

            With ReaderSettings
                .ValidationType = ValidationType.Schema
                .ValidationFlags = XmlSchemaValidationFlags.ProcessSchemaLocation Or XmlSchemaValidationFlags.ReportValidationWarnings Or XmlSchemaValidationFlags.AllowXmlAttributes

                For Each SchemaPath As String In Me.Schemas
                    .Schemas.Add(Nothing, XmlReader.Create(SchemaPath, Me.SchemaSettings))
                Next

                AddHandler .ValidationEventHandler, SchemaValidation
            End With

            Using Reader As XmlReader = XmlReader.Create(New StringReader(RawXml), ReaderSettings)
                While Reader.Read()
                    ' Reads the whole file and will call the validation
                    ' handler subroutine if an error is detected.  Doing
                    ' it this way allows us to pick out ALL of the errors 
                    ' from the XML, rather than bombing out on the first
                    ' one.
                End While
            End Using
        End If

        Return ErrorList
    End Function

    Private Sub ValidationHandler(ByVal sender As Object, ByVal e As System.Xml.Schema.ValidationEventArgs)
        If e.Severity = XmlSeverityType.Error Then
            ErrorList.Add(e.Message)
        End If
    End Sub
End Class

Dim Validator as New XmlValidator()
Dim Errors as List(Of String)
Dim RawXml as String

Using Reader as New StreamReader(Server.MapPath("~/App_Data/test.xml"), Encoding.UTF8)
    RawXml = Reader.ReadToEnd()
End Using

With Validator
    .SchemaSettings.ProhibitDtd = False
    .Schemas.Add(Server.MapPath("~/App_Data/schema1.xsd"))
    .Schemas.Add(Server.MapPath("~/App_Data/schema2.xsd"))

    Errors = .ValidateXml(RawXml)
End With

For Each Err as String In Errors
    Console.WriteLine(Err)
Next