The Blog of Josh Stodola

    ''' <summary>
    ''' Gets the number of subscribers to the specified FeedBurner feed
    ''' </summary>
    ''' <param name="FeedName">The name of the FeedBurner Feed (ex: http://feeds.feedburner.com/NAME_HERE )</param>
    ''' <param name="Cache">Reference to the contexts cache. Pass Nothing if you do not want to store the result in cache.</param>
    ''' <returns>Number of subscribers. Will return zero if an error occurs.</returns>
    Public Shared Function GetNumberOfSubscribers(ByVal FeedName As String, ByRef Cache As Caching.Cache) As Integer
        Const CacheId As String = "Counts.FeedburnerSubscribers"
        Const FeedBurnerApi As String = "http://api.feedburner.com/awareness/1.0/GetFeedData?uri={0}"
        Dim Result As Integer = 0

        If Cache Is Nothing OrElse Cache.Item(CacheId) Is Nothing Then
            Dim Url As String = String.Format(FeedBurnerApi, FeedName)
            Dim FeedBurner As String

            Try
                Using Client As New WebClient()
                    FeedBurner = Client.DownloadString(Url)
                End Using
            Catch ex As WebException
                'Logworthy?
                FeedBurner = String.Empty
            End Try

            If Not String.IsNullOrEmpty(FeedBurner) Then
                Dim XmlDoc As New XmlDocument()
                Dim ResponseNode As XmlNode
                Dim StatusAttribute As XmlAttribute

                Try
                    XmlDoc.LoadXml(FeedBurner)

                    ResponseNode = XmlDoc.SelectSingleNode("rsp")
                    StatusAttribute = ResponseNode.Attributes.ItemOf("stat")

                    If StatusAttribute IsNot Nothing AndAlso StatusAttribute.Value = "ok" Then
                        Dim EntryNode As XmlNode = ResponseNode.SelectSingleNode("feed/entry")

                        If EntryNode IsNot Nothing Then
                            Int32.TryParse(EntryNode.Attributes.ItemOf("circulation").Value, Result)

                            If Cache IsNot Nothing Then
                                Cache.Insert(CacheId, Result, Nothing, Now.AddHours(6), Nothing)
                            End If
                        End If
                    End If
                Catch ex As NullReferenceException
                    'Logworthy?
                End Try
            End If
        Else
            Int32.TryParse(Cache.Item(CacheId).ToString(), Result)
        End If

        Return Result
    End Function