The Blog of Josh Stodola

Imports System.IO
Imports System.Net
Imports System.Web
Imports System.Web.Caching

Public Class Naked
    Implements IHttpHandler

    Private Const NAKED_DAY_API As String = "http://php-naked-day-api.googlecode.com/files/config.json"
    Private Const NAKED_DAY_DEFAULT As Integer = 9 'The default day to use if the API call failed or was invalid (paranoia)
    Private Const CACHE_KEY As String = "Css.NakedDay"
    Private Const CACHE_LIFETIME As Integer = 24 'Number of hours to store the value in Cache

    Public Sub ProcessRequest(ByVal context As System.Web.HttpContext) Implements IHttpHandler.ProcessRequest
        Dim Path As String = context.Request.PhysicalPath

        With context.Response
            If File.Exists(Path) AndAlso Date.Today <> GetNakedDay(context.Cache) Then
                .ContentEncoding = Encoding.UTF8
                .ContentType = "text/css"
                .WriteFile(Path, False)
            Else
                .StatusCode = 404
                .End()
                .Close()
            End If
        End With
    End Sub

    Private Function GetNakedDay(ByRef Cache As Cache) As Date
        Const MONTH As Integer = 4
        Dim NakedDay As Date

        If Cache.Item(CACHE_KEY) Is Nothing Then
            Dim Token As New Regex("""day"" : (\d{1,2})")
            Dim Api As String

            NakedDay = New Date(Date.Now.Year, MONTH, NAKED_DAY_DEFAULT)

            Try
                Using Client As New WebClient()
                    Api = Client.DownloadString(NAKED_DAY_API)
                End Using
            Catch ex As WebException
                Api = String.Empty
            End Try

            If Not String.IsNullOrEmpty(Api) AndAlso Token.IsMatch(Api) Then
                Dim Hold As String() = Token.Matches(Api).Item(0).Value.Split(":")
                NakedDay = New Date(Date.Now.Year, MONTH, CInt(Hold(1).Trim()))

                'Only add the value to cache if the API call was successful
                Cache.Add(CACHE_KEY, NakedDay, Nothing, Date.Now.AddHours(CACHE_LIFETIME), Cache.NoSlidingExpiration, CacheItemPriority.Normal, Nothing)
            End If
        Else
            NakedDay = Date.Parse(Cache.Get(CACHE_KEY))
        End If

        Return NakedDay
    End Function

    Public ReadOnly Property IsReusable() As Boolean Implements IHttpHandler.IsReusable
        Get
            Return False
        End Get
    End Property
End Class

<system.web>
  <httpHandlers>
    <add verb="*" path="*.css" type="Naked" validate="false"/>
  </httpHandlers>
</system.web>