The Blog of Josh Stodola

''' <summary>
''' Returns a string that can be streamed out to an Excel spreadsheet.
''' Records are delimited by a line feed (13). Fields are delimited by a tab (9).
''' </summary>
''' <param name="Objects">The list of class instances to convert</param>
''' <param name="IncludeHeadings">
''' Include a heading record at the beginning of the string? 
''' Headings will be derived from the property name.
''' </param>
''' <param name="IncludeReadOnlyProperties">
''' Include ReadOnly properties in the response for each instance?
''' </param>
''' <returns>Nothing if the given collection is empty</returns>
Public Shared Function ListToString(Of T)(ByVal Objects As List(Of T), ByVal IncludeHeadings As Boolean, ByVal IncludeReadOnlyProperties As Boolean) As String
    If Objects Is Nothing OrElse Objects.Count = 0 Then
        Return Nothing
    End If

    Dim TAB As String = Convert.ToChar(9)
    Dim LF As String = Convert.ToChar(13)
    Dim Result As New StringBuilder()
    Dim Type As Type = GetType(T)
    Dim Props As PropertyInfo() = Type.GetProperties()

    If IncludeHeadings Then
        For Each Prop As PropertyInfo In Props
            If Prop.CanWrite OrElse IncludeReadOnlyProperties Then
                Result.Append(Prop.Name)
                Result.Append(TAB)
            End If
        Next
    End If

    For Each Obj As Object In Objects
        Result.Append(LF)

        For Each Prop As PropertyInfo In Props
            If Prop.CanWrite OrElse IncludeReadOnlyProperties Then
                Result.Append(Prop.GetValue(Obj, Nothing).ToString())
                Result.Append(TAB)
            End If
        Next
    Next

    Return Result.ToString()
End Function

''' <summary>
''' Returns a string that can be streamed out to an Excel spreadsheet.
''' Records are delimited by a line feed (13). Fields are delimited by a tab (9).
''' Includes headings. Excludes read-only properties.
''' </summary>
''' <param name="Objects">The list of class instances to convert</param>
''' <returns>Nothing if the given collection is empty</returns>
Public Shared Function ListToString(Of T)(ByVal Objects As List(Of T)) As String
    Return ListToString(Objects, True, False)
End Function

Structure Employee
    Private _Id As Integer
    Private _Name As String
    Private _DateHired As DateTime

    Sub New(ByVal Id As Integer, ByVal Name As String, ByVal DateHired As DateTime)
        _Id = Id
        _Name = Name
        _DateHired = DateHired
    End Sub

    ReadOnly Property Id() As Integer
        Get
            Return _Id
        End Get
    End Property

    Property Name() As String
        Get
            Return _Name
        End Get
        Set(ByVal value As String)
            _Name = value
        End Set
    End Property

    Property DateHired() As DateTime
        Get
            Return _DateHired
        End Get
        Set(ByVal value As DateTime)
            _DateHired = value
        End Set
    End Property
End Structure

Sub Main()
    Dim MyList As New List(Of Employee)
    Dim RightNow As DateTime = DateTime.Now
    Dim Export As String

    MyList.Add(New Employee(1, "Josh Stodola", RightNow.AddDays(-365)))
    MyList.Add(New Employee(2, "John Doe", RightNow.AddDays(-31)))
    MyList.Add(New Employee(3, "Jane Doe", RightNow))

    Export = Utility.ListToString(MyList)

    Console.WriteLine()
    Console.WriteLine(Export)
    Console.WriteLine()
    Console.ReadLine()
End Sub