The Blog of Josh Stodola

Private Function SortDataTable(ByRef Table as DataTable, ByVal SortString as String) as DataTable
    Dim View as New DataView(Table)
    View.Sort = SortString
    Return View.ToTable()
End Function

Imports System.Collections
Imports System.Collections.Generic
Imports System.Reflection

Namespace Utility

    ''' <summary>
    ''' Sort order enumeration
    ''' </summary>
    Public Enum SortOrder
        Ascending
        Descending
    End Enum

    ''' <summary>
    ''' This instance class is used to sort a generic collection of object instances.
    ''' It automatically fetches the type and performs the necessary comparison(s) to sort.
    ''' 
    ''' To use, instantiate this class, set the sort string property, and pass this
    ''' instance to the internal Sort() function of your generic collection.
    ''' 
    ''' Example:
    '''     Dim MyList As List(Of MyClassType) = 'Populate the list somehow
    '''     Dim Sorter As New Sorter(Of MyClassType)
    '''     Sorter.SortString = "Field1 DESC, Field2"
    '''     MyList.Sort(Sorter) 'After this call, the list is sorted
    ''' </summary>
    Public Class Sorter(Of T)
        Implements IComparer(Of T)

        Private _Sort As String

        ''' <summary>
        ''' Instantiate the class.
        ''' </summary>
        Public Sub New()

        End Sub

        ''' <summary>
        ''' Instantiate the class, setting the sort string.
        ''' 
        ''' Example: "LastName DESC, FirstName"
        ''' </summary>
        Public Sub New(ByVal SortString As String)
            _Sort = SortString
        End Sub

        ''' <summary>
        ''' The sort string used to perform the sort. Can sort on multiple fields.
        ''' Use the property names of the class and basic SQL Syntax.
        ''' 
        ''' Example: "LastName DESC, FirstName"
        ''' </summary>
        Public Property SortString() As String
            Get
                If _Sort IsNot Nothing Then
                    Return _Sort.Trim()
                End If

                Return Nothing
            End Get
            Set(ByVal value As String)
                _Sort = value
            End Set
        End Property

        ''' <summary>
        ''' This is an implementation of IComparer(Of T).Compare
        ''' Can sort on multiple fields, or just one.
        ''' </summary>
        Public Function Compare(ByVal x As T, ByVal y As T) As Integer Implements IComparer(Of T).Compare
            If Not String.IsNullOrEmpty(Me.SortString) Then
                Const ERR As String = "The property ""{0}"" does not exist in type ""{1}"""
                Dim Type As Type = GetType(T)
                Dim Comp As Comparer = Comparer.DefaultInvariant
                Dim Info As PropertyInfo

                For Each Expr As String In Me.SortString.Split(","c)
                    Dim Dir As SortOrder = SortOrder.Ascending
                    Dim Field As String

                    Expr = Expr.Trim()

                    If Expr.EndsWith(" DESC") Then
                        Field = Expr.Replace(" DESC", String.Empty).Trim()
                        Dir = SortOrder.Descending
                    Else
                        Field = Expr.Replace(" ASC", String.Empty).Trim()
                    End If

                    Info = Type.GetProperty(Field)

                    If Info Is Nothing Then
                        Throw New MissingFieldException(String.Format(ERR, Field, Type.ToString()))
                    Else
                        Dim Result As Integer = Comp.Compare(Info.GetValue(x, Nothing), Info.GetValue(y, Nothing))

                        If Result <> 0 Then
                            If Dir = SortOrder.Descending Then
                                Return Result * -1
                            Else
                                Return Result
                            End If
                        End If
                    End If
                Next
            End If

            Return 0
        End Function
    End Class
End Namespace

Module Module1

    Sub Main()
        Dim People As List(Of Person) = GetPeople()
        Dim Sorter As New Sorter(Of Person)

        Sorter.SortString = "FirstName"
        People.Sort(Sorter)
        PrintResults(People, Sorter.SortString)

        Sorter.SortString = "LastName DESC, FirstName, MiddleName"
        People.Sort(Sorter)
        PrintResults(People, Sorter.SortString)

        Sorter.SortString = "DateOfBirth DESC"
        People.Sort(Sorter)
        PrintResults(People, Sorter.SortString)

        Console.ReadLine()
    End Sub

    Function GetPeople() As List(Of Person)
        Dim Result As New List(Of Person)

        With Result
            .Add(New Person("John", "M", "Doe", #1/1/1969#))
            .Add(New Person("Jane", "A", "Doe", #3/4/1972#))
            .Add(New Person("Paul", "L", "Smith", #2/1/1948#))
            .Add(New Person("Janet", "A", "Doe", #9/16/1975#))
            .Add(New Person("Patricia", "B", "Smith", #3/14/1952#))
            .Add(New Person("John", "Matthew", "Doe", #12/21/1988#))
            .Add(New Person("James", "L", "Doe", #6/19/1990#))
            .Add(New Person("Patrick", "O", "Smith", #8/26/1993#))
        End With

        Return Result
    End Function

    Sub PrintResults(ByRef People As List(Of Person), ByVal SortString As String)
        Console.WriteLine("Sort String: " & SortString)
        Console.WriteLine()

        For Each Per As Person In People
            Console.WriteLine(Per.ToString())
        Next

        Console.WriteLine()
        Console.WriteLine()
    End Sub
End Module

Class Person

    Private _First As String
    Private _Middle As String
    Private _Last As String
    Private _Dob As Date

    Sub New()

    End Sub

    Sub New(ByVal FirstName As String, ByVal MiddleName As String, ByVal LastName As String, ByVal DateOfBirth As Date)
        _First = FirstName
        _Middle = MiddleName
        _Last = LastName
        _Dob = DateOfBirth
    End Sub

    Property FirstName() As String
        Get
            Return _First
        End Get
        Set(ByVal value As String)
            _First = value
        End Set
    End Property

    Property MiddleName() As String
        Get
            Return _Middle
        End Get
        Set(ByVal value As String)
            _Middle = value
        End Set
    End Property

    Property LastName() As String
        Get
            Return _Last
        End Get
        Set(ByVal value As String)
            _Last = value
        End Set
    End Property

    Property DateOfBirth() As Date
        Get
            Return _Dob
        End Get
        Set(ByVal value As Date)
            _Dob = value
        End Set
    End Property

    Overrides Function ToString() As String
        Return Me.FirstName.PadRight(15, " ") & _
               Me.MiddleName.PadRight(10, " ") & _
               Me.LastName.PadRight(15, " ") & _
               Me.DateOfBirth.ToString("yyyy-MM-dd")
    End Function
End Class